On the hunt for TTRPGs with annotated ludographies/bibliographies in their text. (In other words, not *just* a list of inspirations) (Bonus points for in-line citations or marginal notes that credit other texts/games/people)
— Dr. Emily Friedman (@friede.bsky.social) 2026-01-15T12:21:17.781Z
En lisant le message de Dr. Emily Friedman sur Bluesky, je me suis souvenu que j’avais des données de recherche sous le coude. Comme j’avais sous-estimé leur intérêt, je ne les avais jamais versé en ligne. Je vais donc rattraper ce retard et progressivement indexer les données dans Wikidata dans les prochains mois.
Bibliographie ou pas
Je vais indiquer si tel jeu ou telle édition de jeu possède :
une bibliographie : une liste simple d’oeuvres ;
ou une bibliographie annotée : une énumération commentée d’oeuvres, sous la forme de liste ou sous la forme de paragraphes rédigés. En effet, elle peut être présentée sous la forme de paragraphes qui se suivent avec un jeu par paragraphes ou par phrases de manière consécutive. Chaque jeu mentionné doit être accompagné d’un commentaire ou d’une annotation spécifique à celui-ci (le plus souvent pour indiquer son apport au jeu) ;
Exemple de bibliographie annotée (Apocalypse World 1st edition) ou des références dans le texte : des mentions à des oeuvres dans un paragraphe de texte. Ces mentions sont insérées dans le texte pour illustrer le discours ou l’argumentation ou pour donner des exemples. Ces mentions listées ne sont pas commentées systématiquement ou spécifiquement. On peut aussi aussi utiliser ceci dans les cas où seulement quelques oeuvres sont mentionnées ;
Exemple de références dans le texte (Aquelarre, 3 ed.) ou des notes de marge : des petits blocs de texte présentés en annotation dans les marges. NB : contrairement aux 3 premiers éléments, ces marginalia ne contiennent pas forcément des références. ;
ou des notes de bas de page : des petits blocs de texte présentés en annotation dans le bas des pages. NB : contrairement aux 3 premiers éléments, ces notes de bas de page ne contiennent pas forcément des références.
ou des filmographies : des listes de films ; ou des listes de musiques ou de groupes ; ou des listes de jeux vidéo.
Je pense que je rajouterai automatiquement des ludographies à partir des citations de jeux de rôles déjà faites.
Indexation
Pour indexer ces éléments, dans Wikidata j’utilise la propriété uses (P2283) avec la valeur :
- bibliography Q1631107
- ou annotated bibliography Q4769616
- ou inline reference Q137842886
- ou marginalia Q1572441
- ou footnote Q25424643
- ou filmography Q1371849
- ou list of music references Q19220511
- ou bibliographical list of video games Q137859315
- ou ludography Q60586493
Ensuite, dans les qualifiers, je rajoute le nombre d’oeuvres présentes avec la propriété Number of records (P4876). Dans le cas où j’ai listé plusieurs types de bibliographie, ce nombre compte le nombre spécifique de référence de chaque type (ex: bibliography = 12; inline = 5). Dans le cas où j’ai fait une généralité, ce nombre reflète le total (ex: bibliography = 12+5 = 17).
Enfin, j’utilise aussi Page(s) (P304) dans References pour indiquer la page ou l’intervalle de page où se trouve la bibliographie dans le jeu.
Je n’ai pas (encore) trouvé comment indiquer élégamment qu’un jeu ne possède pas de bibliographie.
Exemples d’indexations
SPARQL
Voici la requête pour afficher toutes les données :
SELECT ?item ?itemLabel ?usesLabel ?NbOfRecords ?AtPages WHERE {
# items is a TTRPG or a TTRPG supplement
VALUES ?TTRPGset {wd:Q1643932 wd:Q71631512}
?item wdt:P31 ?TTRPGset.
# Find items where P2283 (uses) is either bibliography or annotated bib. or inline ref. or marginalia or footnote...
?item p:P2283 ?statement.
?statement ps:P2283 ?uses.
FILTER(?uses IN (wd:Q4769616, wd:Q1631107, wd:Q137842886, wd:Q1572441, wd:Q25424643, wd:Q1371849, wd:Q19220511, wd:Q137859315, wd:Q60586493))
# Optional: Get qualifier P4876 (number of records)
OPTIONAL { ?statement pq:P4876 ?NbOfRecords. }
# Optional: Get reference P304 (page(s))
OPTIONAL {
?statement prov:wasDerivedFrom ?reference.
?reference pr:P304 ?AtPages.
}
# Get labels for display
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}Points notables
Le jeu le plus remarquable pour son énorme bibliographie annotée est A Game of Thrones d20 (2005) qui contient un essai complet sur la fantasy avec 379 références à l’intérieur du livre de règles (pp. 21-35).
Le plus ancien jeu avec des références dans le texte est D&D (1974), avec une attribution médiocrement reconnaissante envers la campagne de Blackmoor de Dave Arneson, matrice du game design des jeux de rôle sur table tels que nous les connaissons aujourd’hui.
Rapidement, les premiers jeux tels que Tunnels & Trolls ou RuneQuest ont cité D&D avant d’arrêter. Voir mon billet sur les Ceases & Desists (en français, in English) sur le sujet.
Le jeu le plus ancien avec une bibliographie est [à déterminer]. Le jeu le plus ancien avec une bibliographie annotée est [à déterminer].
Épigraphes
J’avais commencé à indexer la présence d’épigraphes dans les jeux de rôle sur table.
J’avais aussi utilisé la propriété uses avec comme valeur :
epigraph (Q669777) avec comme qualifiers :
quantity (P1117)
has characteristic (P1552) = referenced value (Q71536081)
fictional quotation (Q18011336)
quantity (P1117)
has characteristic (P1552) = in-universe perspective (Q96102813)
Exemple
Requête pour afficher l’indexation des épigraphes
SELECT ?epigraph ?epigraphLabel ?usesLabel ?quantity WHERE {
# items is a TTRPG
?epigraph wdt:P31 wd:Q1643932.
# Find items where P2283 (uses) is either Q669777 (epigraph) or Q18011336 (fictional quotation)
?epigraph p:P2283 ?statement.
?statement ps:P2283 ?uses.
FILTER(?uses IN (wd:Q669777, wd:Q18011336))
# Optional: Get qualifier P1114 (quantity)
OPTIONAL { ?statement pq:P1114 ?quantity. }
# Get labels for display
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}